Open SAS Enterprise Guide

Open New Project

Open New Program

To open an Excel file, use PROC IMPORT. Code for our Excel file is:

**Proc** **import** datafile='N:\SAS Workshop 1 Folder\Workshop file.xlsx'

out=OUT1

replace;

sheet='First file';

**run**;

Comments:

* Datafile = the file containing the Excel File
* Out = Out1 creates a file in the SAS Work Library
* REPLACE allows you to overwrite a previous version of OUT1
* Sheet = ‘First File’ tells SAS to read the sheet called “First File”. If this is not given, the default is “Sheet1”.

To add some labels and formats to the variables in OUT1:

First we create the formats:

**proc** **format**;

value $sex 'M'='Male'

 'F'='Female';

value $rank 'FR'='Freshman'

 'SO'='Sophomore'

 'JR'='Junior'

 'SR'='Senior';

value $dist 'A'='Within 50 miles of GVSU'

 'B'='Over 50 miles from GVSU but in MI'

 'C'='Outside of MI';

value Q1\_ **1**='Strongly Disagree'

 **2**='Disagree'

 **3**='Neutral'

 **4**='Agree'

 **5**='Strongly Agree';

**run**;

* *Value* is used for each format that is created.
* The formats that are created are $sex, $rank, $dist, and Q1\_
* $sex, $rank and $dist have dollar signs because the format is for character variables.
* Q1\_ has an underscore because a format cannot end in a number.

We now apply the formats to the values of the variables. We also create labels for the variable names themselves:

**data** out1;\*output data set;

set out1;\*input data set;

label Rank='Class Rank'

 high\_school='How far is your High School from GVSU?'

 speed='Fastest speed ever driven a car'

 seed='How far did you spit the sunflower seed? (ft)'

 Q1='Likert Scale responses to Question 1';

format sex $sex. rank $rank. high\_school $dist. Q1 Q1\_.;

**run**;

Remaining code is below. Title and Footnote statements are used to document the code:

title 'Lists all variables in the data set';

title2 'Labels created above are not applied';

**proc** **print** data=out1;

**run**;

title 'Lists only the variables after VAR';

title2 'label statement applies the labels to the variables';

**proc** **print** data=out1 label;

var CASEID rank speed;

**run**;

title 'default summary statistics';

**proc** **means** data=out1;

var speed seed;

**run**;

title 'Must sort data set BY the variable';

title2 'before using PROC MEANS with the BY variable';

**proc** **sort** data=out1;

by rank;

**run**;

title 'Speed separated by class rank';

title2 'Specific statistics are specified';

footnote 'clm=confidence interval for mean';

footnote2 'alpha = 0.10--90% CI';

footnote3 'maxdec= 2 means 2 decimal places in printout';

**proc** **means** data=out1 clm mean std alpha=**0.10** maxdec=**2**;

var speed;

by rank;

**run**;

title 'default frequency table for rank';

**proc** **freq** data=out1;

tables rank;

**run**;

title 'tables for rank and Q1';

title2 'nocum and nopercent suppresses percents';

**proc** **freq** data=out1;

tables rank Q1/nocum nopercent;

**run**;

title '\* creates a crosstabs table';

**proc** **freq** data=out1;

tables Q1\*sex;

**run**;

title 'norow, nocol, nopercent suppresses percents';

title2 'chisq gives chi square numbers';

**proc** **freq** data=out1;

tables Q1\*sex/norow nocol nopercent chisq;

**run**;

title "Gives 'kitchen sink' statistics";

title2 'normal gives normality tests';

title3 'plot gives some descriptive plots';

**proc** **univariate** data=out1 normal plot;

var seed;

**run**;

title 'vertical bar chart for seed-default';

**proc** **gchart** data=out1;

vbar seed;

**run**;

title 'sets classes for vertical bar chart';

title2 'classes: 0-40, 40-80, etc.';

**proc** **gchart** data=out1;

vbar seed/midpoints=**20** to **220** by **40**;

**run**;

title 'vertical bar chart with 6 levels';

**proc** **gchart** data=out1;

vbar seed/levels=**6**;

**run**;

title 'horizontal bar chart for Q1';

title2 'discrete tells SAS to treat Q1 as categorical variable';

**proc** **gchart** data=out1;

hbar Q1/discrete;

**run**;

title 'default pie chart';

**PROC** **GCHART** DATA=out1;

 PIE Q1;

**RUN**;

title 'pie chart with extras';

**PROC** **GCHART** DATA=out1;

 PIE Q1/ DISCRETE VALUE=INSIDE

 PERCENT=INSIDE SLICE=OUTSIDE;

**RUN**;

**On Exporting Results**

Click on the Results tab for options. We will talk through these.

To copy tables or graphs into Word:

* Right click on the desired graph and choose “Copy”.
* Go to a blank Word document, right click, under Paste choose “Keep Source Formatting” (the first logo).
* To save the graph as a JPEG item, right click to “Save as”, find a location to save it, and then save the JPEG document.
* Finally, open and paste your JPEG document into Word.

The Seed graph is below.



Next is the fancy pie chart for Q1.



**Some Help Resources**

* <https://support.sas.com/documentation/>: Has a lot of stuff, but sometimes hard to use.
* <http://www.lexjansen.com/>: Has over 27,000 SAS User Group papers and SAS Proceedings. Many of these are tutorials on various components and tools in SAS, from beginning level to advanced level.
* <http://www.ats.ucla.edu/stat/sas/> From the UCLA Institute for digital research and education. This is a great resource for those wanting good, clear examples of code and printout. Often when I have to recall something or want a simple example, one of their websites is the place to go.
* Google in general: Google some words related to what you are looking for, and then start digging through web pages.

**Books**

There are many good SAS books out there. The three I list below are what I would consider to be “must

haves” for a beginner.

* *Learning SAS by Example: A Programmer’s Guide*, Ron Cody, SAS Institute. I have used this book before in my classes, and still use it for examples. Some of the material about the SAS output

file is out of date since SAS went to HTML as the default.

* *SAS Statistics by Example,* Ron Cody, SAS Institute. A good resource for doing much of the

material you’d do in the first two college-level statistics courses, plus logistic regression.

* *The Little SAS Book, A Primer, 5th Edition*, by Delwiche and Slaughter. I am using this book in my 616 and have used it in 318 (the undergraduate SAS programming course). It is a good source of instruction for a SAS beginner.